#!/usr/bin/perl
# -*- Mode: perl -*-
# file: qtl_study

use lib '/usr/local/gramene/lib/perl/';
use strict;
use vars qw($DB);
use Ace 1.51;
use Ace::Browser::AceSubs qw(:DEFAULT Toggle);
use GrameneSubs;
use CGI 2.42 qw/:standard :html3 escape *table *ul *blockquote/;

use constant CLASS   => 'QTL_study';
#use constant EXAMPLE => 'QTL-Yield-Waiyin2/CB';

# open the database
$DB = OpenDatabase() || AceError("Couldn't open database.");

my ($obj_name, $obj);
$obj_name = param('name');
$obj = get_obj($obj_name) if $obj_name;

PrintTop($obj,CLASS,$obj ? CLASS . ": $obj" : CLASS . " Search");
PrintWarning($obj_name,CLASS) if $obj_name && !$obj;
if ($obj){
  print_study_information($obj);
  print_qtls($obj);
}
PrintBottom();

sub get_obj {
  my $name = shift;
  my ($obj) = $DB->fetch(-class =>CLASS,
			 -name  => $name);
  return $obj;
}


sub print_study_information {
  my $study = shift;

  print h2('Study Information');

  print start_table({-border=>1});

  if (my $a = $study->Locality) {
    print TR(
	   th({-class=>'datatitle'},'Locality'),
	   td({-class=>'databody'},$a)
	   );
  }

  if (my $a = $study->Taxon) {
    print TR(
	   th({-class=>'datatitle'},'Taxon'),
 	   td({-class=>'databody'},ObjectLink($a))
	   );
  }
  if ((my $a = $study->Female_parent) && (my $b = $study->Male_parent)) {
    print TR(
	   th({-class=>'datatitle'},'Cross (Male x Female)'),
 	   td({-class=>'databody'},ObjectLink($a),'x',ObjectLink($b))
	    );
  }
  if ((my $a = $study->Population)) {
    print TR(
	   th({-class=>'datatitle'},'Population'),
 	   td({-class=>'databody'},$a)
	    );
  }
  if (my @r = $study->Reference) {
    print TR(
	   th({-class=>'datatitle'},'Reference(s)'),
	   td({-class=>'databody'},ObjectLink(shift @r))
	   );
    foreach (@r) {
      print TR(
	       th({-class=>'datatitle'},'&nbsp;'),
	       td({-class=>'databody'},ObjectLink($_))
	      );
    }
  }
  print end_table;
}
sub print_qtls {
  my $obj = shift;
  my @qtls = $obj->Qtl or return;
  print h2('QTLs Mapped in this Study');
  print start_ul;
  for my $qtl (@qtls) {
    my $trait = $qtl->Trait;
    print li(ObjectLink($qtl),$trait);
  }
  print end_ul;
}
